GOAT VRF

Consumer contract
      |
      v
Request randomness from GoatVRF
      |
      v
Oracle service watches requests
      |
      v
drand proof submitted onchain
      |
      v
Consumer callback receives randomness

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

contract MyRandomContract is IRandomnessCallback {
  using SafeERC20 for IERC20;

  address public goatVRF;
  address public owner;

  modifier onlyOwner() {
    require(msg.sender == owner, "Only owner");
    _;
  }

  constructor(address goatVRF_) {
    goatVRF = goatVRF_;
    owner = msg.sender;
  }

  function getNewRandom(uint256 maxAllowedGasPrice) external onlyOwner returns (uint256 requestId) {
    address tokenAddress = IGoatVRF(goatVRF).feeToken();
    uint256 callbackGas = 600000;
    uint256 fee = IGoatVRF(goatVRF).calculateFeeWithGasPrice(callbackGas, maxAllowedGasPrice);

    IERC20 token = IERC20(tokenAddress);
    uint256 safetyMargin = fee * 3 / 2;
    token.forceApprove(goatVRF, safetyMargin);

    IDrandBeacon beacon = IDrandBeacon(IGoatVRF(goatVRF).beacon());
    uint256 deadline = block.timestamp + beacon.period();
    requestId = IGoatVRF(goatVRF).getNewRandom(deadline, maxAllowedGasPrice, callbackGas);
  }

  function receiveRandomness(uint256 requestId, uint256 randomness) external override {
    require(msg.sender == goatVRF, "Only GoatVRF can fulfill randomness");

    // Use randomness in your application.
    // For example: selectWinner(requestId, randomness);
  }
}

interface IRandomnessCallback {
  function receiveRandomness(uint256 requestId, uint256 randomness) external;
}

interface IDrandBeacon {
  function period() external view returns (uint256);
}

interface IGoatVRF {
  function calculateFee(uint256 gas) external view returns (uint256 totalFee);

  function calculateFeeWithGasPrice(uint256 gas, uint256 gasPrice) external view returns (uint256 totalFee);

  function getNewRandom(uint256 deadline, uint256 maxAllowedGasPrice, uint256 callbackGas)
    external
    returns (uint256 requestId);

  function cancelRequest(uint256 requestId) external;

  function beacon() external view returns (address beaconAddr);

  function feeToken() external view returns (address tokenAddr);
}

uint256 fee = IGoatVRF(goatVRF).calculateFee(600000);
uint256 feeWithLimit = IGoatVRF(goatVRF).calculateFeeWithGasPrice(600000, 0.01 gwei);

address tokenAddress = IGoatVRF(goatVRF).feeToken();
IERC20 token = IERC20(tokenAddress);
token.forceApprove(goatVRF, fee * 3 / 2);

IDrandBeacon beacon = IDrandBeacon(IGoatVRF(goatVRF).beacon());
uint256 deadline = block.timestamp + beacon.period();

forge build
forge test
forge script script/Deploy.s.sol --rpc-url <rpc_url> --private-key <your_private_key> --broadcast